💻

Estrutura Condicional - Parte 2

1 - Estruturas Condicionais – (Estruturas de Controle - Escolha)

Conceito: Uma estrutura condicional “escolha” permite enfileirar vários blocos de comandos, utilizada quando se tem várias estruturas de decisão (SE-ENTÃO-SENÃO) aninhadas. Isto é, quando outras verificações são feitas caso a anterior tenha falhado (ou seja, o fluxo do algoritmo entrou no bloco SENÃO). A proposta da estrutura ESCOLHA-CASO é permitir ir direto ao bloco de código desejado, dependendo do valor de uma variável de verificação. Vamos ver o esquema abaixo.

1.1 - Estruturas Condicionais Escolha-Caso

Escolha <variável de verificação>
	Caso <valor1> 
		 <comando 1>
		 <comando 2>
		 <comando n>
	Caso <valor2>
		 <comando 1>
		 <comando 2>
		 <comando n>
	Caso <valor3>
		 <comando 1>
		 <comando 2>
		 <comando n>
	Caso <valor 4>
		 <comando 1>
		 <comando 2>
		 <comando n>
	OutroCaso
		 <comando 1>
		 <comando 2>
		 <comando n>
fimescolha

1.2 - Comparação com o Se-Então-Senão-FimSe

Algoritmo "dia_da_semana_se_senao"
// Disciplina  : Lógica de Programação
// Descrição   : Exercício - Dia da semana - com se/senao
// Autor(a)    : Professor Mauro Borges França
// Data atual  : 09/04/2025
var
   dia: inteiro
inicio
   escreva("Digite um número de 1 a 7: ")
   leia(dia)

   se dia = 1 entao
      escreval("Domingo")
   senao
      se dia = 2 entao
         escreval("Segunda-feira")
      senao
         se dia = 3 entao
            escreval("Terça-feira")
         senao
            se dia = 4 entao
               escreval("Quarta-feira")
            senao
               se dia = 5 entao
                  escreval("Quinta-feira")
               senao
                  se dia = 6 entao
                     escreval("Sexta-feira")
                  senao
                     se dia = 7 entao
                        escreval("Sábado")
                     senao
                        escreval("Número inválido")
                     fimse
                  fimse
               fimse
            fimse
         fimse
      fimse
   fimse
fimalgoritmo
💡

Observação: Veja como os SEs-Senão deixam o código mais complexo. A lógica funciona e é entendível, porém não fica legal. Veja no exemplo abaixo como ficaria este mesmo algoritmo utilizando a estrutura escolha.

Algoritmo "dia_da_semana_escolha"
// Disciplina  : Lógica de Programação
// Descrição   : Exercício - Dia da semana - estrutura escolha
// Autor(a)    : Professor Mauro Borges França
// Data atual  : 09/04/2025
var
   dia: inteiro
inicio
   escreva("Digite um número de 1 a 7: ")
   leia(dia)
   escreva("Dia da semana: ")
   escolha dia
      caso 1
          escreval("Domingo")
      caso 2
          escreval("Segunda-feira")
      caso 3
          escreval("Terça-feira")
      caso 4
          escreval("Quarta-feira")
      caso 5
          escreval("Quinta-feira")
      caso 6
          escreval("Sexta-feira")
      caso 7
          escreval("Sábado")
      outrocaso
         escreval("Número inválido")
   fimescolha
fimalgoritmo
💡

Observação: Bem mais organizado e elegante, a lógica fica bem mais clara. Em comparação, a lógica dos dois algoritmos é a mesma, funciona sem problemas, porém para algumas soluções o uso da estrutura escolha é mais adequada para aplicação.

Outra Observação: A opção “outrocaso” é opcional, porém muito útil e é bem provável que será utilizado na maioria das aplicações.

👩‍💻Lista 05 - Exercícios de Algoritmos - Estrutura Condicional - Parte 3

Copyleft 🄯 2025 - Professor Mauro Borges França.